The Elder Scrolls V: Skyrim

Scriptname DRWMESurvivalStateAdjust extends ActiveMagicEffect  
{
General function to adust survival pools.
Can be used for any sort of effect: Food, Drink, Disease, Poison, Drugs.

Magnitude: If defined, it will override the magnitude from the spell. Use for predefined effects. Must be a positive value but can be used with Decrease.
Recover: Use for drugs, poison and diseases, not for food and drink items
Decrease: Decrease the value. Use for negative effects like dehydration.
Modifier: Use for effects which should decrease or increase 
}
Float Property Magnitude = 0.0 Auto
Bool Property Recover = true Auto
Bool Property Decrease = false Auto
Bool Property IsModifier    = false Auto
Keyword Property NeedsType Auto
DRWQuestGameSurvival Property  SurvivalQuest Auto

Event OnEffectStart(Actor akTarget, Actor akCaster)
    if self && akTarget
        Debug.Trace("DRW - Survival - Effect " + self + " - OnEffectStart")
        if Magnitude != 0.0
            SurvivalQuest.ModifyStatus(NeedsType, Magnitude, Decrease, IsModifier)
        else
            SurvivalQuest.ModifyStatus(NeedsType, self.GetMagnitude(), Decrease, IsModifier)
        endif
    endif
EndEvent

Event OnEffectFinish(Actor akTarget, Actor akCaster)
    if Recover == true
        if self && akTarget
            Debug.Trace("DRW - Survival - Effect " + self + " - OnEffectFinish")
            if Magnitude != 0.0
                SurvivalQuest.ModifyStatus(NeedsType, Magnitude, !Decrease, IsModifier)
            else
                SurvivalQuest.ModifyStatus(NeedsType, self.GetMagnitude(), !Decrease, IsModifier)
            endif
        endif
    endif
EndEvent

Scriptname DRWQuestGameSurvival extends Quest  Conditional
{
 Applies spells and other effects based on the current settings, difficulty, and state.
 All effects must be applied by spells: Imagespaces, visual effects, buffs, penalties, ...
 Resistances and other modifiers must be defined by a given spell. 
 The control quest gives only the ticks and changes to the appropriate spell per level.
 The main interval of the quest is an hour. All values are recalculated  once per game hour.
 You can use the XXXLevel properties as conditions  in spells.
}
; Condition system
Float Property StateFood Auto Conditional
Float Property StateDrink Auto Conditional
Float Property StateSleep Auto Conditional
Float Property StatePoison Auto Conditional
Float Property StateDisease Auto Conditional
Float Property StateCannabis Auto Conditional
Float Property StateAlcohol Auto Conditional
Float Property StateDrug Auto Conditional
Float Property StateHappiness Auto Conditional
Float Property StateAdrenaline Auto Conditional
Float Property StateWerewolf Auto Conditional    ; 0 No beast blood, 1 Beast Blood, 2 Werewolf form
Float Property StateVampire Auto Conditional    ; 0 No vampire, 1-4 Vampire level, 5 Vampire Lord
Float Property StateDay Auto Conditional
Float Property StateSleeping Auto Conditional

; Keyword system
Keyword Property DRWTypeFood Auto
Keyword Property DRWTypeDrink Auto
Keyword Property DRWTypeSleep Auto
Keyword Property DRWTypePoison Auto
Keyword Property DRWTypeDisease Auto
Keyword Property DRWTypeCannabis Auto
Keyword Property DRWTypeAlcohol Auto
Keyword Property DRWTypeDrug Auto
Keyword Property DRWTypeHappiness Auto
Keyword Property DRWTypeAdrenaline Auto
; Spell system: Displays the various states
Spell[] Property DRWSpellFood Auto
Spell[] Property DRWSpellDrink Auto
Spell[] Property DRWSpellSleep Auto
Spell[] Property DRWSpellPoison Auto
Spell[] Property DRWSpellDisease Auto
Spell[] Property DRWSpellCannabis Auto
Spell[] Property DRWSpellAlcohol Auto
Spell[] Property DRWSpellDrug Auto
Spell[] Property DRWSpellHappiness Auto
Spell[] Property DRWSpellAdrenaline Auto
; Other properties
Race Property VampireLordRace auto
Race Property WerewolfBeastRace Auto
Spell Property BeastForm auto
PlayerVampireQuestScript Property PlayerVampireQuest Auto
FormList Property DRWTypeSurvivalList Auto
FormList Property DRWTypeSurvivalInteriorList Auto
GlobalVariable Property GameHour Auto
GlobalVariable Property DRWGlobalSurvivalVersion Auto
GlobalVariable Property DRWGlobalSurvivalDifficulty Auto
; Private vars
Bool initOnce        = false
Float version         = -1.0        ; Quest version
Float difficulty    = -1.0        ; Current difficulty
Bool isReady         = false        ; Initial config done
Bool isBlocked        = false        ; Blocked
Bool threadLock     = false        ; Thread lock flag
float updateSingle    = 60.0        ; Update interval in seconds
float updateTime    = 1.0         ; Update interval in game hours
Int threadIndex     = 1            ; Count of attempts to wait for a new thread
Float[] foodState
Float[] drinkState
Float[] sleepState
Float[] poisonState
Float[] diseaseState
Float[] cannabisState
Float[] alcoholState
Float[] drugState
Float[] happinessState
Float[] adrenalineState

; Adjusts a state as defined by the configuration, using the current penalty  modifier.
; Can be used by any scripted magic effect of type fire and forget or constant with duration.
; The value is set once by the magic effect or by quest.
Function ModifyStatus(Keyword Type, float Magnitude, bool Decrease = false, bool IsModifier = false)
    _debugTrace("ModifyStatus", "Function called. Affected pool: " + Type)
    if _getRunning()
        _setThreadLock()
        Float[] source = _getSource(Type)
        if IsModifier
            if Decrease
                _modifyState(source, 0.0 - Magnitude)
            else
                _modifyState(source, Magnitude)
            endif
        else
            _modifyMult(source, Magnitude)
        endif
    endif
    _resetThreadLock()
EndFunction

; Adjusts a state as defined by the configuration, using the current penalty  modifier.
; Can be used by food and beverage.
; The value is set once by the magic effect or by quest.
Float Function GetStatus(Keyword Type)
    Float[] source = _getSource(Type)
    return _getStateLevel(source)
EndFunction

; Init quest.
Event OnInit()
    if initOnce == false
        initOnce = true
        _debugTrace("OnInit", "Quest Started")
        _reset(true)
        _startUpdate()
    endif
EndEvent

; Game load.
Event OnPlayerLoadGame()
    _reset(false)
EndEvent

; Receives single updates.
Event OnUpdate()
    if _getRunning()
        _onUpdateSingle()
    endif
EndEvent

; Receives game time updates.
Event OnUpdateGameTime()
    if _getRunning()
        _onUpdateTime()
    endif
EndEvent

; Sleep start event.
Event OnSleepStart(float afSleepStartTime, float afDesiredSleepEndTime)
    ; Debug.Trace("Player went to sleep at: " + Utility.GameTimeToString(afSleepStartTime))
endEvent

; Sleep end event.
Event OnSleepStop(bool abInterrupted)
    ; To do
EndEvent

; Update function in seconds. 
Function _onUpdateSingle()
    ; To do
    RegisterForSingleUpdate(updateSingle)
EndFunction

; Update function in seconds. 
Function _onUpdateTime()
    _updateValues()
    _updateConditions()
    _updateSpells()
    RegisterForSingleUpdateGameTime(updateTime)
EndFunction

; Starts updates.
Function _startUpdate()
    RegisterForSleep()
    RegisterForSingleUpdate(updateSingle)
    RegisterForSingleUpdateGameTime(updateTime)
EndFunction

; Stops updates. Doesn't stop or lock the quest.
Function _stopUpdate()
    UnregisterForSleep()
    UnregisterForUpdate()
    UnregisterForUpdateGameTime()
EndFunction

; Applies all spells and other effects based on the current settings.
Function _updateSpells()
    int len = DRWTypeSurvivalList.GetSize()
    int index = 0
    while index < len
        _updateSpell(DRWTypeSurvivalList.GetAt(index) as Keyword)
          index = index + 1
    endwhile
EndFunction

; Applies spells and other effects based on the current settings.
; All effects must be applied by the spell: Imagespaces, visuall effects, buffs, penalties, ...
; Resistances and other modifiers must be defined by the spell. The control quest gives only the ticks.
Function _updateSpell(Keyword type)
    int index         = 0
    float[] source     = _getSource(type)
    int level         = _getStateLevel(source) As Int
    spell[] spells     = _getSpell(type)
    int len         = spells.Length
    actor player     = Game.GetPlayer()
    ; _debugTrace("updateSpell", "Trying to update spell for type " + type + " and level " + level)
    while index < len
        player.DispelSpell(spells[index])
          index = index + 1
    endwhile
    if level <= len && level > 0
        player.AddSpell(spells[level - 1], false) ; The array is zero-based.
    else
        _debugTrace("updateSpell", "No spell for type " + type + " and level " + level + " found.")
    endif
EndFunction

; Updates a target source.
Function _updateValues()
    int len = DRWTypeSurvivalList.GetSize()
    int index = 0
    while index < len
        _updateValue(DRWTypeSurvivalList.GetAt(index) as Keyword)
          index = index + 1
    endwhile
EndFunction

Function _updateValue(Keyword type)
    Float[] source = _getSource(type)
    Float[] target = _recalcSource(source)
    if type == DRWTypeFood
        foodState     = target
        StateFood     = _getStateLevel(target)
    elseif type == DRWTypeDrink
        drinkState     = target
        StateDrink     = _getStateLevel(target)
    elseif type == DRWTypeSleep
        sleepState     = target
        StateSleep     = _getStateLevel(target)
    elseif type == DRWTypePoison
        poisonState     = target
        StatePoison     = _getStateLevel(target)
    elseif type == DRWTypeDisease
        diseaseState     = target
        StateDisease     = _getStateLevel(target)
    elseif type == DRWTypeCannabis
        cannabisState     = target
        StateCannabis     = _getStateLevel(target)
    elseif type == DRWTypeAlcohol
        alcoholState     = target
        StateAlcohol    = _getStateLevel(target)
    elseif type == DRWTypeDrug
        drugState     = target
        StateDrug     = _getStateLevel(target)
    elseif type == DRWTypeHappiness
        happinessState     = target
        StateHappiness     = _getStateLevel(target)
    elseif type == DRWTypeAdrenaline
        adrenalineState     = target
        StateAdrenaline     = _getStateLevel(target)
    else
        _debugTrace("updateValue", "Keyword " + type + " not found.")
    endif
EndFunction

; Updates a target source.
Function _updateConditions()
    Actor player = Game.GetPlayer()
     ; 0 No beast blood, 1 Beast Blood, 2 Werewolf form
    if player.GetRace() == WerewolfBeastRace
        StateWerewolf = 2
    elseif player.HasSpell(BeastForm)
        StateWerewolf = 1
    else
        StateWerewolf = 0
    endif
    ; 0 No vampire, 1-4 Vampire level, 5 Vampire Lord
    if player.GetRace() == VampireLordRace
        StateVampire = 5
    else
        StateVampire = PlayerVampireQuest.VampireStatus ; These cock suckers weren't professional enough to implement a conditional state. Have to find a more complicated wqay for release.
    endif
    StateDay = _getDayState()
EndFunction

; Returns a source.
Float[] Function _getSource(Keyword type)
    if type == DRWTypeFood
        return foodState
    elseif type == DRWTypeDrink
        return drinkState
    elseif type == DRWTypeSleep
        return sleepState
    elseif type == DRWTypePoison
        return poisonState
    elseif type == DRWTypeDisease
        return diseaseState
    elseif type == DRWTypeCannabis
        return cannabisState
    elseif type == DRWTypeAlcohol
        return alcoholState
    elseif type == DRWTypeDrug
        return drugState
    elseif type == DRWTypeHappiness
        return happinessState
    elseif type == DRWTypeAdrenaline
        return adrenalineState
    else
        _debugTrace("getSource", "No data source for type " + type + " found.")
        return new Float[6]
    endif
EndFunction

; Returns a spell list.
Spell[] Function _getSpell(Keyword type)
    if type == DRWTypeFood
        return DRWSpellFood
    elseif type == DRWTypeDrink
        return DRWSpellDrink
    elseif type == DRWTypeSleep
        return DRWSpellSleep
    elseif type == DRWTypePoison
        return DRWSpellPoison
    elseif type == DRWTypeDisease
        return DRWSpellDisease
    elseif type == DRWTypeCannabis
        return DRWSpellCannabis
    elseif type == DRWTypeAlcohol
        return DRWSpellAlcohol
    elseif type == DRWTypeDrug
        return DRWSpellDrug
    elseif type == DRWTypeHappiness
        return DRWSpellHappiness
    elseif type == DRWTypeAdrenaline
        return DRWSpellAdrenaline
    else
        _debugTrace("getSpell", "No spell list for type " + type + " found.")
        return new Spell[6]
    endif
EndFunction

; Returns the current level of a state.
Float Function _getStateLevel(Float[] stateSource)
    Float vmin
    Float vmax
    Float val         = stateSource[0]
    Float tick         = stateSource[2]
    Float states     = stateSource[3]
    Float level     = -1.0
    Int index         = 1
    While index as Float <= states && level == -1.0
        vmax = index * tick
        vmin = vmax - tick
        if val >= vmin && val < vmax
            level = index
        endif
        index = index + 1
    EndWhile
    return level
EndFunction

; Modifies a state to positive or negative.
Float[] Function _modifyState(Float[] stateSource, Float magnitude)
    float newState = _calcNewVal(stateSource[0], magnitude, stateSource[1])
    if newState < 0
        stateSource[0] = 0.0
    elseif newState > stateSource[2] * stateSource[3]
        stateSource[0] = stateSource[2] * stateSource[3]
    else
        stateSource[0] = newState
    endif
    return stateSource
EndFunction

Float[] Function _recalcSource(Float[] stateSource)
    ; For now. TO DO!!!!!!!!!!
    return stateSource
EndFunction

; Calculates a new pool value.
Float Function _calcNewVal(Float val, Float magnitude, Float modifier)
    Float newVal = 0.0
    if magnitude < 0.0
        if modifier < 0.0 ; Value should decrease, modifier is negative = value is decreased more
            newVal = val - (magnitude / 100 * (100 + Math.Abs(modifier)))
        else ; Value should decrease, modifier is positive  = value is decreased less
            newVal = val - (magnitude / 100 * (100 - Math.Abs(modifier)))
        endif
    elseif magnitude > 0.0
        if modifier < 0.0 ; Value should increase, modifier is negative = value is increased less.
            newVal = val + (magnitude / 100 * (100 - Math.Abs(modifier)))
        else     ; Value should increase, modifier is positive = value is increased more.
            newVal = val + (magnitude / 100 * (100 + Math.Abs(modifier)))
        endif
    else
        newVal = val
    endif
    return newVal
EndFunction

; Modifies a modifier.
Float[] Function _modifyMult(Float[] stateSource, Float multModifier)
    Float mult     = stateSource[1]
    Float newMult = mult + multModifier
    if newMult < -100.0
        stateSource[1] = -100.0
    elseif newMult > 100.0
        stateSource[1] = 100.0
    else
        stateSource[1] = newMult
    endif
    return stateSource
EndFunction

; Default configuration of the states.
Function _reset(bool forced = false)
    _debugTrace("_reset", "Survival mode reset.  Forced: " + forced)
    float lastValue    = version
    if version != DRWGlobalSurvivalVersion.GetValue() || forced == true 
        version = DRWGlobalSurvivalVersion.GetValue()
        if lastValue == -1.0 ; First start
            _resetConfig()
            _updateConditions()
            _updateSpells()
        elseif lastValue == 0.1 
            ; Do something
        elseif forced == true 
            _resetConfig()
            _updateConditions()
            _updateSpells()
        endif
    endif
    lastValue = difficulty
    if difficulty != DRWGlobalSurvivalDifficulty.GetValue()
        difficulty = DRWGlobalSurvivalDifficulty.GetValue()
        if lastValue == -1.0 ; Disabled or first start
            ; Do something
        elseif difficulty == 3.0 && lastValue == 0.0
            ; Do something
        endif
    endif
    isReady = true
EndFunction

; Default configuration of the states.
Function _resetConfig()
    foodState             = new Float[6]
    foodState[0]         = 250.0        ; State (0 to Tick * States)
    foodState[1]         = 0.0        ; Mult (-100 to 100)
    foodState[2]         = 100.0        ; Tick
    foodState[3]         = 7.0        ; States (There has to be a spell for every state)
    foodState[4]        = 20.0        ; State decrease per hour
    foodState[5]        = 10.0        ; Mult change per hour towards zero.
    drinkState             = new Float[6]
    drinkState[0]         = 250.0        ; State (0 to Tick * States)
    drinkState[1]         = 0.0        ; Mult (-100 to 100)
    drinkState[2]         = 100.0        ; Tick
    drinkState[3]         = 7.0        ; States (There has to be a spell for every state)
    drinkState[4]        = 20.0        ; State decrease per hour
    drinkState[5]        = 10.0        ; Mult change per hour towards zero.
    sleepState             = new Float[6]
    sleepState[0]         = 450.0        ; State (0 to Tick * States)
    sleepState[1]         = 0.0        ; Mult (-100 to 100)
    sleepState[2]         = 100.0        ; Tick
    sleepState[3]         = 7.0        ; States (There has to be a spell for every state)
    sleepState[4]        = 20.0        ; State decrease per hour
    sleepState[5]        = 10.0        ; Mult change per hour towards zero.
    poisonState         = new Float[6]
    poisonState[0]         = 0.0        ; State (0 to Tick * States)
    poisonState[1]         = 0.0        ; Mult (-100 to 100)
    poisonState[2]         = 100.0        ; Tick
    poisonState[3]         = 7.0        ; States (There has to be a spell for every state)
    poisonState[4]        = 20.0        ; State decrease per hour
    poisonState[5]        = 10.0        ; Mult change per hour towards zero.
    diseaseState         = new Float[6]
    diseaseState[0]     = 150.0        ; State (0 to Tick * States)
    diseaseState[1]     = 0.0        ; Mult (-100 to 100)
    diseaseState[2]     = 100.0        ; Tick
    diseaseState[3]     = 7.0        ; States (There has to be a spell for every state)
    diseaseState[4]        = 20.0        ; State decrease per hour
    cannabisState         = new Float[6]
    cannabisState[0]     = 0.0        ; State (0 to Tick * States)
    cannabisState[1]     = 0.0        ; Mult (-100 to 100)
    cannabisState[2]     = 100.0        ; Tick
    cannabisState[3]     = 7.0        ; States (There has to be a spell for every state)
    cannabisState[4]    = 20.0        ; State decrease per hour
    cannabisState[5]    = 10.0        ; Mult change per hour towards zero.
    alcoholState         = new Float[6]
    alcoholState[0]     = 0.0        ; State (0 to Tick * States)
    alcoholState[1]     = 0.0        ; Mult (-100 to 100)
    alcoholState[2]     = 100.0        ; Tick
    alcoholState[3]     = 7.0        ; States (There has to be a spell for every state)
    alcoholState[4]        = 20.0        ; State decrease per hour
    alcoholState[5]        = 10.0        ; Mult change per hour towards zero.
    drugState             = new Float[6]
    drugState[0]         = 0.0        ; State (0 to Tick * States)
    drugState[1]         = 0.0        ; Mult (-100 to 100)
    drugState[2]         = 100.0        ; Tick
    drugState[3]         = 7.0        ; States (There has to be a spell for every state)
    drugState[4]        = 20.0        ; State decrease per hour
    drugState[5]        = 10.0        ; Mult change per hour towards zero.
    happinessState         = new Float[6]
    happinessState[0]     = 550.0        ; State (0 to Tick * States)
    happinessState[1]     = 0.0        ; Mult (-100 to 100)
    happinessState[2]     = 100.0        ; Tick
    happinessState[3]     = 7.0        ; States (There has to be a spell for every state)
    happinessState[4]    = 20.0        ; State decrease per hour
    happinessState[5]    = 10.0        ; Mult change per hour towards zero.
    adrenalineState     = new Float[6]
    adrenalineState[0]     = 650.0        ; State (0 to Tick * States)
    adrenalineState[1]     = 0.0        ; Mult (-100 to 100)
    adrenalineState[2]     = 100.0        ; Tick
    adrenalineState[3]     = 7.0        ; States (There has to be a spell for every state)
    adrenalineState[4]    = 20.0        ; State decrease per hour
    adrenalineState[5]    = 10.0        ; Mult change per hour towards zero.
EndFunction

; Player environment
; 0: Interior
; 1: Day [8.00 - 18.00]
; 2: Night [21.00 - 5.00]
; 3: Dawn [5.00 - 8.00]
; 4: Dusk [18.00 - 21.00]
int Function _getDayState()
    int aType = 0
    If (_isInInterior() == false) ; Aussenzonen
        float currentHour = GameHour.GetValue()
        If (currentHour  >= 8 && currentHour  <= 18) ; Day
            aType = 1
        ElseIf (currentHour < 5 || currentHour > 21) ; Night
            aType = 2
        ElseIf (currentHour  >= 5 && currentHour  < 8) ; Dawn
            aType = 3
        Else ; Dusk
            aType = 4
        EndIf
    EndIf
    return aType
EndFunction

; Check for fake worldspaces, especially caves
bool function _isInInterior()
    if Game.GetPlayer().IsInInterior()
        return true
    else
        if DRWTypeSurvivalInteriorList.HasForm(Game.GetPlayer().GetWorldSpace())
            return true
        else
            return false
        endif
    endif
endFunction

; Utility function to check if the system is running.
Bool Function _getRunning()
    return isReady == true && isBlocked == false
EndFunction

; Utility function to wait for edit lock.
Function _setThreadLock()
    threadIndex += 1
    while threadLock
        Utility.Wait(0.1 * threadIndex)
    endWhile
    threadLock = true
    threadIndex -= 1
EndFunction

; Utility function to reset edit lock.
Function _resetThreadLock()
    threadLock = false
EndFunction

; Debug utility.
Function _debugTrace (string area, string trace)
    Debug.Trace( "DRW - Survival - " + area + " > " + trace) 
EndFunction